• Loi de Pareto (règle des 80/20) : une petite partie des produits, ou des clients, fait l'essentiel du chiffre d'affaires.
• Le classement ABC en découle : on trie les produits du plus vendu au moins vendu, on cumule leur CA, puis A jusqu'à 80 % du CA, B jusqu'à 95 %, C au-delà. Usage : priorités de stock, de négociation, de suivi commercial.

• Pareto_Depart : le modèle et les consignes. Décompressez le dossier, puis ouvrez le fichier .pbip.
• Jeu de données fictif (commun aux cas Pareto, RFM, clients et panier croisé) : un vendeur de vélos et d'accessoires, 940 clients, 24 produits, 2 456 commandes et 4 470 lignes en 2024 et 2025.
• Mesures fournies : CA = SUM ( Ventes[Montant] ) et Nb commandes = DISTINCTCOUNT ( Ventes[NumCommande] ).
• Corrigé : le PBIP Pareto_Corrige est remis par le formateur.

Part du CA = DIVIDE ( [CA], CALCULATE ( [CA], ALLSELECTED ( Produit[Produit] ) ) )

• ALLSELECTED retire le filtre de la ligne (le produit) mais garde ceux des segments : la somme des parts affichées fait toujours 100 %.
• Source (Microsoft Learn)

CA cumulé =
IF (
    HASONEVALUE ( Produit[Produit] ),
    VAR ca = [CA]
    RETURN
        SUMX (
            FILTER ( ALLSELECTED ( Produit[Produit] ), [CA] >= ca ),
            [CA]
        )
)

• La variable ca fige le CA du produit courant avant l'itération ; dans FILTER, [CA] est recalculé pour chaque produit de la liste (transition de contexte).
• HASONEVALUE laisse la ligne de total vide.

% cumulé = DIVIDE ( [CA cumulé], CALCULATE ( [CA], ALLSELECTED ( Produit[Produit] ) ) )

Classe ABC =
IF (
    HASONEVALUE ( Produit[Produit] ),
    VAR avant = [% cumulé] - [Part du CA]
    RETURN
        SWITCH ( TRUE (), avant < 0.8, "A", avant < 0.95, "B", "C" )
)

• La classe se décide sur le pourcentage cumulé avant le produit : le produit qui fait franchir le seuil des 80 % reste en A. Sans cette précaution, si le premier produit pesait à lui seul 85 % du CA, aucun produit ne serait en A.
• Source (Microsoft Learn)

• Tableau : Produit, CA, Part du CA, CA cumulé, % cumulé, Classe ABC, trié par CA décroissant.
• Graphique combiné (histogramme groupé et graphique en courbes) : axe X = Produit, colonnes = CA, ligne = % cumulé, trié par CA décroissant. C'est la courbe de Pareto. Ajoutez une ligne constante à 80 % dans le volet Analytique.

Nb produits A = COUNTROWS ( FILTER ( ALLSELECTED ( Produit[Produit] ), [Classe ABC] = "A" ) )

• La mesure se place dans une carte. Elle réutilise la classe de chaque produit grâce à la transition de contexte.

• 5 produits sur 24 (21 %) font 85 % du CA : classe A. 6 produits en B, 13 en C.
• Avec le segment Catégorie = Accessoires, le Pareto se recalcule sur les 8 accessoires : Casque, Antivol, Compteur GPS et Sacoche passent en A.

• Pareto des clients : remplacez Produit[Produit] par Client[Client] dans toutes les mesures.
• Ex aequo : deux produits de même CA reçoivent le même CA cumulé. Pour les départager, ajoutez un critère secondaire (par exemple le nom) dans le FILTER.
• Voir aussi la question 3.5 de la Mise en pratique DAX.