• Objectifs : écrire une fonction DAX réutilisable ; choisir le type et le mode de passage de ses paramètres ; l'enregistrer dans le modèle et l'appeler depuis une mesure.
• Prérequis : « Vue de requête DAX », « Itérateurs et variables ».
• Niveau : avancé.
• Disponibilité : fonctionnalité en disponibilité générale dans Power BI Desktop et le service Power BI depuis la version de juin 2026 ; niveau de compatibilité du modèle 1702 ou supérieur.

DEFINE
    /// Description de la fonction
    FUNCTION <NomFonction> = ( [<parametre> [: <type>] [<sous-type>] [<mode>] [= <valeur par défaut>], ...] ) => <corps de la fonction>

• Le nom ne contient que des lettres, des chiffres et des tirets bas ; il peut contenir des points pour créer un espace de noms (Ventes.Part), mais ne peut ni commencer ni finir par un point. Il ne doit pas reprendre le nom d'une fonction DAX native ni un mot réservé.
• Une fonction accepte de 0 à 256 paramètres ; une valeur par défaut rend un paramètre facultatif.
• Les commentaires /// placés au-dessus de la fonction deviennent sa description dans IntelliSense.

• Dans la vue de requête DAX : définissez et testez la fonction, puis cliquez sur Mettre à jour le modèle : Ajouter une nouvelle fonction (ou Mettre à jour le modèle avec les modifications).
• Dans la vue TMDL : écrivez la fonction avec le mot-clé function, puis appliquez.
• Dans le service Power BI, avec l'édition web des modèles sémantiques.

DEFINE
    /// Renvoie la part du numérateur dans le dénominateur, vide si le dénominateur est nul
    FUNCTION Part = ( numerateur : NUMERIC, denominateur : NUMERIC ) =>
        DIVIDE ( numerateur, denominateur )

EVALUATE
{ Part ( 25, 200 ) }
// Renvoie 0,125

% ALL Produit = Part ( [Montant vente], CALCULATE ( [Montant vente], ALL ( Produit ) ) )

DEFINE
    /// Calcule une expression pour une seule couleur de produit
    FUNCTION PourCouleur = ( expression : EXPR, couleur : STRING ) =>
        CALCULATE ( expression, Produit[Couleur] = couleur )

EVALUATE
SUMMARIZECOLUMNS (
    Geographie[Pays],
    "Montant", [Montant vente],
    "Montant rouge", PourCouleur ( [Montant vente], "Rouge" )
)

DEFINE
    FUNCTION AjouterTaxe = ( montant : NUMERIC, taux : NUMERIC = 0.2 ) => montant * ( 1 + taux )

    FUNCTION PrixRemiseTTC = ( montant : NUMERIC, remise : NUMERIC ) => AjouterTaxe ( montant * ( 1 - remise ) )

EVALUATE
{ PrixRemiseTTC ( 100, 0.1 ) }
// Renvoie 108

• Choisissez le mode de passage : VAL pour une valeur déjà calculée, EXPR dès que la fonction applique un filtre ou un itérateur à l'argument.
• Pas de récursivité ni de surcharge : une fonction ne peut pas s'appeler elle-même, et deux fonctions ne peuvent pas porter le même nom avec des paramètres différents.
• Pas de dossier d'affichage ni de masquage pour les fonctions ; pas de type de retour explicite.
• Sécurité : la sécurité au niveau objet (OLS) ne s'applique pas aux fonctions ; évitez de révéler le nom d'objets protégés dans le nom ou la description d'une fonction.
• IntelliSense : il n'y a pas d'IntelliSense pour les UDF dans la barre de formule des calculs visuels.
• Documentez chaque fonction avec des commentaires /// : ils s'affichent quand vous l'utilisez dans une mesure.
• Préfixez vos fonctions par un espace de noms (GD.Part, Ventes.Part) pour les distinguer des fonctions natives et des bibliothèques partagées.

• Une UDF se définit avec FUNCTION Nom = ( paramètres ) => corps, puis s'enregistre dans le modèle.
• Elle s'appelle dans une mesure, une colonne calculée ou un calcul visuel comme une fonction native.
• VAL évalue l'argument avant l'appel, EXPR le réévalue dans la fonction.
• Les UDF sont en disponibilité générale depuis juin 2026 (niveau de compatibilité 1702).

• Source (Microsoft Learn, fonctions définies par l'utilisateur dans Power BI)
• Source (Microsoft Learn, syntaxe et types des UDF)
• Source (SQLBI)
• Fonctions définies par l'utilisateur (UDF) (Support Formation DAX, GD Solutions)