• Chaque mois, on répartit les clients actifs en nouveaux (première commande ce mois-ci) et récurrents (déjà clients avant).
• On compte aussi les clients perdus : ceux qui ont cessé de commander. Le solde (nouveaux moins perdus) indique si la base de clients grandit ou s'érode.

• ClientsNouveauxPerdus_Depart : le modèle et les consignes. Jeu de données commun aux cas d'étude (940 clients, 2 456 commandes en 2024 et 2025).
• Corrigé : le PBIP ClientsNouveauxPerdus_Corrige est remis par le formateur.

Clients actifs = DISTINCTCOUNT ( Ventes[ClientID] )

Nouveaux clients =
VAR debut = MIN ( Calendrier[Date] )
RETURN
    COUNTROWS (
        FILTER (
            VALUES ( Ventes[ClientID] ),
            CALCULATE ( MIN ( Ventes[Date] ), ALL ( Calendrier ) ) >= debut
        )
    )

• debut est lu hors du FILTER : c'est le premier jour de la période affichée (mois, trimestre ou année).
• Pour chaque client actif, CALCULATE transforme la ligne en filtre sur le client, et ALL ( Calendrier ) retire le filtre du mois : on obtient sa toute première commande.
• Le client est nouveau si cette première commande tombe dans la période.
• Source (Microsoft Learn)

Clients récurrents = [Clients actifs] - [Nouveaux clients]

Clients perdus =
VAR debut = MIN ( Calendrier[Date] )
VAR fin = MAX ( Calendrier[Date] )
VAR clientsM3 =
    CALCULATETABLE (
        VALUES ( Ventes[ClientID] ),
        DATESBETWEEN ( Calendrier[Date], EOMONTH ( debut, -4 ) + 1, EOMONTH ( debut, -3 ) )
    )
RETURN
    COUNTROWS (
        FILTER (
            clientsM3,
            ISEMPTY (
                CALCULATETABLE (
                    Ventes,
                    DATESBETWEEN ( Calendrier[Date], EOMONTH ( debut, -3 ) + 1, fin )
                )
            )
        )
    )

• EOMONTH ( debut, -4 ) + 1 et EOMONTH ( debut, -3 ) donnent le premier et le dernier jour du mois M-3.
• clientsM3 est la liste des clients qui ont commandé en M-3. Pour chacun, ISEMPTY vérifie qu'il n'a aucune vente entre le début de M-2 et la fin de M.
• La mesure se lit au niveau du mois. Les trois premiers mois de 2024 n'ont pas de clients perdus : il n'y a pas de données avant janvier 2024.
• Source (Microsoft Learn)

Solde clients = [Nouveaux clients] - [Clients perdus]

• Matrice : Calendrier[Annee] et Calendrier[Mois] en lignes, les cinq mesures en valeurs.
• Histogramme empilé : axe X = Calendrier[DebutMois], valeurs = Nouveaux clients et Clients récurrents. La hauteur totale est le nombre de clients actifs.
• Graphique combiné : nouveaux et perdus en colonnes, solde en ligne.

• Sur l'année 2025 : 619 clients actifs, dont 421 nouveaux et 198 récurrents.
• À partir de l'été 2024, le solde devient négatif : l'acquisition ralentit alors que les départs restent nombreux. C'est le constat que l'Analyse de cohortes permet ensuite d'expliquer.

• Clients réactivés : clients actifs en M, perdus auparavant (plus de trois mois sans commande avant M).
• CA par type de client : CALCULATE ( [CA], FILTER ( VALUES ( Ventes[ClientID] ), ... ) ) avec la même condition que les nouveaux clients.